KF2-CustomTraderInventory/CTI/Classes/CTI_RepInfo.uc

403 lines
9.0 KiB
Ucode
Raw Normal View History

2023-10-01 22:55:09 +00:00
class CTI_RepInfo extends ReplicationInfo
dependson(WeaponReplacements);
2023-05-12 23:33:32 +00:00
const CAPACITY = 64; // max: 128
2023-05-12 23:33:32 +00:00
const Trader = class'Trader';
const LocalMessage = class'CTI_LocalMessage';
2023-10-01 22:55:09 +00:00
const Replacements = class'WeaponReplacements';
2023-05-12 23:33:32 +00:00
struct ReplicationStruct
{
var int Size;
var int Transfered;
var class<KFWeaponDefinition> Items[CAPACITY];
var int Length;
};
2023-05-12 23:33:32 +00:00
var public bool PendingSync;
var private CTI CTI;
var private E_LogLevel LogLevel;
var private KFPlayerController KFPC;
2023-10-01 22:55:09 +00:00
var private KFPlayerReplicationInfo KFPRI;
2023-05-12 23:33:32 +00:00
var private KFGFxWidget_PartyInGame PartyInGameWidget;
var private GFxObject Notification;
var private String NotificationHeaderText;
var private String NotificationLeftText;
var private String NotificationRightText;
var private int NotificationPercent;
var private int WaitingGRI;
2023-05-13 23:20:31 +00:00
var private int WaitingGRILimit;
2023-05-12 23:33:32 +00:00
var private ReplicationStruct RepData;
var private Array<class<KFWeaponDefinition> > RepArray;
2023-10-01 22:55:09 +00:00
var private bool SkinUpdateRequired;
2023-05-12 23:33:32 +00:00
replication
{
if (bNetInitial && Role == ROLE_Authority)
2023-10-01 22:55:09 +00:00
LogLevel, SkinUpdateRequired;
2023-05-12 23:33:32 +00:00
}
public simulated function bool SafeDestroy()
{
`Log_Trace();
return (bPendingDelete || bDeleteMe || Destroy());
}
public function Replicate(const out Array<class<KFWeaponDefinition> > WeapDefs)
{
`Log_Trace();
RepArray = WeapDefs;
RepData.Size = RepArray.Length;
if (WorldInfo.NetMode == NM_StandAlone)
{
Progress(RepArray.Length, RepArray.Length);
return;
}
Sync();
}
private reliable server function Sync()
{
local int LocalIndex;
local int GlobalIndex;
`Log_Trace();
LocalIndex = 0;
GlobalIndex = RepData.Transfered;
while (LocalIndex < CAPACITY && GlobalIndex < RepData.Size)
{
RepData.Items[LocalIndex++] = RepArray[GlobalIndex++];
}
if (RepData.Transfered == GlobalIndex) return; // Finished
RepData.Transfered = GlobalIndex;
RepData.Length = LocalIndex;
Send(RepData);
Progress(RepData.Transfered, RepData.Size);
}
private reliable client function Send(ReplicationStruct RD)
{
local int LocalIndex;
`Log_Trace();
for (LocalIndex = 0; LocalIndex < RD.Length; LocalIndex++)
{
RepArray.AddItem(RD.Items[LocalIndex]);
}
Progress(RD.Transfered, RD.Size);
Sync();
}
2023-10-01 22:55:09 +00:00
public function PrepareSync(CTI _CTI, KFPlayerController _KFPC, E_LogLevel _LogLevel, bool _SkinUpdateRequired)
{
`Log_Trace();
2023-10-01 22:55:09 +00:00
CTI = _CTI;
KFPC = _KFPC;
LogLevel = _LogLevel;
SkinUpdateRequired = _SkinUpdateRequired;
}
private simulated function Progress(int Value, int Size)
{
`Log_Trace();
`Log_Debug("Replicated:" @ Value @ "/" @ Size);
if (ROLE < ROLE_Authority)
{
NotifyProgress(Value, Size);
if (Value >= Size) Finished();
}
}
private simulated function Finished()
2023-05-12 23:33:32 +00:00
{
local KFGameReplicationInfo KFGRI;
2023-05-12 23:33:32 +00:00
`Log_Trace();
if (WorldInfo.GRI == None && WaitingGRI++ < WaitingGRILimit)
{
`Log_Debug("Finished: Waiting GRI" @ WaitingGRI);
NotifyWaitingGRI();
SetTimer(1.0f, false, nameof(Finished));
return;
}
KFGRI = KFGameReplicationInfo(WorldInfo.GRI);
if (KFGRI != None)
{
`Log_Debug("Finished: Trader.static.OverwriteTraderItems");
Trader.static.OverwriteTraderItems(KFGRI, RepArray, LogLevel);
`Log_Info("Trader items successfully synchronized!");
}
else
{
`Log_Error("Incompatible Replication info:" @ String(WorldInfo.GRI));
NotifyIncompatibleGRI();
}
ShowReadyButton();
2023-10-01 22:55:09 +00:00
if (SkinUpdateRequired)
{
SetTimer(1.0f, true, nameof(UpdateSkinsDLC));
}
else
{
ClientCleanup();
}
}
private simulated function UpdateSkinsDLC()
{
local SWeapReplace WeapReplace;
`Log_Debug("Wait for spawn");
if (GetKFPRI() != None && KFPRI.bHasSpawnedIn)
{
foreach Replacements.default.DLC(WeapReplace)
{
if (WeapReplace.WeapParent.default.SkinItemId > 0 && WeapReplace.Weap.default.SkinItemId != WeapReplace.WeapParent.default.SkinItemId)
{
`Log_Debug("Update skin for:" @ String(WeapReplace.WeapDef) @ "SkinId:" @ WeapReplace.WeapParent.default.SkinItemId);
class'KFWeaponSkinList'.static.SaveWeaponSkin(WeapReplace.WeapDef, WeapReplace.WeapParent.default.SkinItemId);
}
}
ClearTimer(nameof(UpdateSkinsDLC));
ClientCleanup();
}
2023-05-12 23:33:32 +00:00
}
private simulated function KFPlayerController GetKFPC()
{
`Log_Trace();
if (KFPC != None) return KFPC;
KFPC = KFPlayerController(Owner);
if (KFPC == None && ROLE < ROLE_Authority)
{
KFPC = KFPlayerController(GetALocalPlayerController());
}
return KFPC;
}
2023-10-01 22:55:09 +00:00
private simulated function KFPlayerReplicationInfo GetKFPRI()
{
`Log_Trace();
if (KFPRI != None) return KFPRI;
if (GetKFPC() == None) return None;
KFPRI = KFPlayerReplicationInfo(KFPC.PlayerReplicationInfo);
return KFPRI;
}
2023-05-13 23:20:31 +00:00
public reliable client function WriteToChatLocalized(
E_CTI_LocalMessageType LMT,
optional String HexColor,
optional String String1,
optional String String2,
optional String String3)
{
`Log_Trace();
WriteToChat(LocalMessage.static.GetLocalizedString(LogLevel, LMT, String1, String2, String3), HexColor);
}
public reliable client function WriteToChat(String Message, optional String HexColor)
{
local KFGFxHudWrapper HUD;
`Log_Trace();
if (GetKFPC() == None) return;
if (KFPC.MyGFxManager.PartyWidget != None && KFPC.MyGFxManager.PartyWidget.PartyChatWidget != None)
{
KFPC.MyGFxManager.PartyWidget.PartyChatWidget.SetVisible(true);
KFPC.MyGFxManager.PartyWidget.PartyChatWidget.AddChatMessage(Message, HexColor);
}
HUD = KFGFxHudWrapper(KFPC.myHUD);
if (HUD != None && HUD.HUDMovie != None && HUD.HUDMovie.HudChatBox != None)
{
HUD.HUDMovie.HudChatBox.AddChatMessage(Message, HexColor);
}
}
2023-05-12 23:33:32 +00:00
private simulated function SetPartyInGameWidget()
{
`Log_Trace();
if (GetKFPC() == None) return;
if (KFPC.MyGFxManager == None) return;
if (KFPC.MyGFxManager.PartyWidget == None) return;
PartyInGameWidget = KFGFxWidget_PartyInGame(KFPC.MyGFxManager.PartyWidget);
Notification = PartyInGameWidget.Notification;
}
private simulated function bool CheckPartyInGameWidget()
{
`Log_Trace();
if (PartyInGameWidget == None)
{
SetPartyInGameWidget();
}
return (PartyInGameWidget != None);
}
private simulated function HideReadyButton()
{
`Log_Trace();
if (CheckPartyInGameWidget())
{
PartyInGameWidget.SetReadyButtonVisibility(false);
}
}
private simulated function ShowReadyButton()
{
`Log_Trace();
ClearTimer(nameof(KeepNotification));
2023-05-12 23:33:32 +00:00
if (CheckPartyInGameWidget())
{
Notification.SetVisible(false);
PartyInGameWidget.SetReadyButtonVisibility(true);
PartyInGameWidget.UpdateReadyButtonText();
PartyInGameWidget.UpdateReadyButtonVisibility();
}
}
private simulated function UpdateNotification(String Title, String Left, String Right, int Percent)
{
`Log_Trace();
if (CheckPartyInGameWidget() && Notification != None)
{
Notification.SetString("itemName", Title);
Notification.SetFloat("percent", Percent);
Notification.SetInt("queue", 0);
Notification.SetString("downLoading", Left);
Notification.SetString("remaining", Right);
Notification.SetObject("notificationInfo", Notification);
Notification.SetVisible(true);
}
}
private simulated function KeepNotification()
{
HideReadyButton();
UpdateNotification(
NotificationHeaderText,
NotificationLeftText,
NotificationRightText,
NotificationPercent);
}
2023-10-01 22:55:09 +00:00
private simulated function ClientCleanup()
{
`Log_Debug("Cleanup");
2023-10-01 22:55:09 +00:00
ServerCleanup();
SafeDestroy();
}
private reliable server function ServerCleanup()
2023-05-12 23:33:32 +00:00
{
`Log_Trace();
`Log_Debug("Cleanup" @ GetKFPC() @ GetKFPRI() == None? "" : GetKFPRI().PlayerName);
if (!CTI.DestroyRepInfo(GetKFPC()))
2023-05-12 23:33:32 +00:00
{
`Log_Debug("Cleanup (forced)");
SafeDestroy();
2023-05-12 23:33:32 +00:00
}
}
2023-05-12 23:33:32 +00:00
private simulated function NotifyWaitingGRI()
{
if (!IsTimerActive(nameof(KeepNotification)))
2023-05-13 23:20:31 +00:00
{
SetTimer(0.1f, true, nameof(KeepNotification));
2023-05-13 23:20:31 +00:00
}
2023-05-12 23:33:32 +00:00
NotificationHeaderText = LocalMessage.static.GetLocalizedString(LogLevel, CTI_WaitingGRI);
NotificationLeftText = String(WaitingGRI) $ LocalMessage.static.GetLocalizedString(LogLevel, CTI_SecondsShort);
NotificationRightText = LocalMessage.static.GetLocalizedString(LogLevel, CTI_PleaseWait);
NotificationPercent = 0;
KeepNotification();
2023-05-12 23:33:32 +00:00
}
private simulated function NotifyProgress(int Value, int Size)
2023-05-12 23:33:32 +00:00
{
if (!IsTimerActive(nameof(KeepNotification)))
2023-05-12 23:33:32 +00:00
{
SetTimer(0.1f, true, nameof(KeepNotification));
2023-05-12 23:33:32 +00:00
}
NotificationHeaderText = LocalMessage.static.GetLocalizedString(LogLevel, CTI_SyncItems);
NotificationLeftText = Value @ "/" @ Size;
NotificationRightText = LocalMessage.static.GetLocalizedString(LogLevel, CTI_PleaseWait);
NotificationPercent = (float(Value) / float(Size)) * 100;
KeepNotification();
2023-05-12 23:33:32 +00:00
}
private simulated function NotifyIncompatibleGRI()
2023-05-12 23:33:32 +00:00
{
WriteToChatLocalized(
CTI_IncompatibleGRI,
class'KFLocalMessage'.default.InteractionColor,
String(WorldInfo.GRI.class));
WriteToChatLocalized(
CTI_IncompatibleGRIWarning,
class'KFLocalMessage'.default.InteractionColor);
2023-05-12 23:33:32 +00:00
}
defaultproperties
{
bAlwaysRelevant = false
bOnlyRelevantToOwner = true
bSkipActorPropertyReplication = false
PendingSync = false
NotificationPercent = 0
WaitingGRI = 0
WaitingGRILimit = 30
2023-05-12 23:33:32 +00:00
}